<!-- VertexShader code here -->
<script id="vertexShader" type="x-shader/x-vertex">#version 300 es
precision highp float;
in vec4 vPosition;
void main() {
	gl_Position = vPosition;
}
</script>
<!-- FragmentShader code here -->
<script id="fragmentShader" type="x-shader/x-fragment">#version 300 es
precision highp float;
out vec4 fragColor;
  
uniform vec4 mouse;
uniform vec2 resolution;
uniform float time;

#define R           resolution
#define T           time
#define M           mouse

#define PI  3.141592653
#define PI2 6.283185307

mat2 rot (float a) { return mat2(cos(a),sin(a),-sin(a),cos(a)); }
float hash21( vec2 p ) { return fract(sin(dot(p,vec2(23.43,84.21))) *4832.3234); }
float hash(in float n){return fract(sin(n)*43.54); }

float noise(in vec2 x) {
    vec2 p = floor(x);
    vec2 f = fract(x);
    f = f*f*(3.-2.*f);
    float n = p.x + p.y*57.;
    float res = mix(mix( hash(n+  0.1), hash(n+  1.1),f.x),
                    mix( hash(n+ 57.1), hash(n+ 58.1),f.x),f.y);
    return res;
}

//@iq
float box( vec3 p, vec3 b ){
    vec3 q = abs(p)-b;
    return length(max(q,0.0)) + min(max(q.x,max(q.y,q.z)),0.0);
}
float box( in vec2 p, in vec2 b ){
    vec2 d = abs(p)-b;
    return length(max(d,0.0)) + min(max(d.x,d.y),0.0);
}

vec3 hit,hitPoint;
vec2 gid,sid;

//@blackle domain rep trick using neighbor 
vec2 edge(vec2 p) {
    vec2 p2 = abs(p);
    if (p2.x > p2.y) return vec2((p.x < 0.) ? -1. : 1., 0.);
    else             return vec2(0., (p.y < 0.) ? -1. : 1.);
}

vec2 map(vec3 p) {  
    p.y+=4.;
	vec2 res = vec2(100.,-1.);

    vec2 center = floor(p.xz) + .5;
    vec2 tpos   = (p.xz - center);
    vec2 neighb = center + edge(tpos);

    float hs = hash21(center);
    float h2 = hash21(center.yx);
    float chk = mod(center.y+center.x,2.)*2.-1.;
    
    float height = .25 + .15 * sin(center.y+T *1.25);
    height += .25 + .15 * sin(center.x+T *.75);
    height += 2.;
    float sh = height;
    height = chk<.5 ? (1.1*hs)+2.:height;
    
    float tval = hs>.75?(tpos.x+.5):hs>.5?(tpos.y+.5):hs>.25?(1.5-tpos.y):(1.5-tpos.x);
    
    float width = .4825;
    vec3 bxs = vec3(width,height+clamp(tval*.4,.0,1.),width);
    
    float me = box(p - vec3(center.x, height,center.y), bxs);
    bxs.y = 4.35;
    float nx = box(p - vec3(neighb.x, height,neighb.y), bxs);
    if (h2>.5&&chk<.5) me = max(me,-box(p-vec3(center.x,height,center.y), vec3(width*.69,height*1.5,width*.69)) );
    float bx = min(me, nx);
    if(bx<res.x) {
        res = vec2(bx,chk>.5?2.:3.);
    	hit = p-vec3(center.x,height,center.y);
        gid = center;
    }  

    float d2 = p.y+5.;
    if(d2<res.x) {
        res = vec2(d2,1.);
    	hit = p;
    }

    vec3 q3 = p-vec3(center.x, height+.25+sh,center.y);
    float d3 = length(q3)-.225;
    if(d3<res.x && (h2>.7&&chk<.5)) {
        res = vec2(d3,5.);
    	hit = q3;
    }
    
    return res;
}

vec3 normal(vec3 p, float t, float mindist){
    float e = mindist*t;
    vec2 h = vec2(1.,-1.);
    return normalize( h.xyy*map( p + h.xyy*e).x + 
					  h.yyx*map( p + h.yyx*e).x + 
					  h.yxy*map( p + h.yxy*e).x + 
					  h.xxx*map( p + h.xxx*e).x );
}

vec3 hue(float t){ 
    vec3 d = vec3(.627,.961,.220);
    return .35 + .375*cos(PI2*t*(vec3(.985,.98,.95)+d)); 
}

vec3 getWood(vec3 p, vec3 clr){
    const vec3 wax = normalize(vec3(1,0,1));
    vec3 uv = (p + dot(p,wax)*wax*14.5)*1.20;
    float wood = 0.;
    wood += abs(noise(uv.xz*5. )-.5);
    wood += abs(noise(uv.yz*8. )-.5)/2.;
    wood += abs(noise(uv.zy*11.)-.5)/4.;
    wood = pow(1.-clamp(wood,.0,1.),5.);
    return mix(clr,vec3(.204,.075,.016),wood);
}

//@Shane AO
float getao(in vec3 p, in vec3 n){
    float sca = 2., occ = 0.;
    for( int i = 0; i<5; i++ ){
        float hr = float(i + 1)*.05/1.5; 
        float d = map(p + n*hr).x;
        occ += (hr - d)*sca;
        sca *= .9;
        if(sca>1e5) break;
    }
    return clamp(1. - occ, 0., 1.);
}

vec3 render(vec3 p, vec3 rd, vec3 ro, float d, float m, inout vec3 n){
    n = normal(p,d,1.01);
    vec3 lpos = vec3(25,25,-25);
    vec3 l = normalize(lpos-p);

    float diff = clamp(dot(n,l),.1,1.);
    
    float fresnel = pow(clamp(1.+dot(rd, n), 0., 1.), 9.);
    fresnel = mix(.0, .9, fresnel);
        
    float shdw = 1.,t=.2;
    for(float i=.0;i<12.;i++) {
        float h = map(p + l*t).x;
        if( h<1e-4 ) { shdw = .05; break; }
        shdw = min(shdw, 75.*h/t);
        t += h * .8;
        if( shdw<.05 || t>32. ) break;
    }
    diff = mix(diff,diff*shdw,.25);
    
    float ao = getao(p,n);
    diff = mix(diff,diff*ao,.75);
    
    vec3 h = vec3(.08);

    if(m==1.) h=getWood(hitPoint,vec3(.506,.314,.094));

    if(m==2.) h=mix(vec3(.00),hue(hash21(sid*.0005)+fresnel),fresnel);

    if(m==3.) {
        float hs = hash21(sid+1.);
        vec3 clr = hs>.65?vec3(0.698,0.318,0.063):hs>.5?vec3(0.882,0.529,0.200):hs>.15?vec3(.427,.15,.03):vec3(0.537,0.294,0.122);
        h=getWood(hitPoint,clr);

        vec2 uv = hitPoint.xz;
        float px = .02;

        float d = box(uv,vec2(.35));
        d=smoothstep(px,-px,abs(abs(d)-.05)-.025);
        h=mix(h,h*vec3(.565,.306,.137),d);  
    }
    
    if(m==5.) h=vec3(.7);
    
    return diff*h;
}

void main( ) {
    vec2 F = gl_FragCoord.xy;
    vec2 uv = (2.*F.xy-R.xy)/max(R.x,R.y);
    vec3 ro = vec3(15,2,3.25),
         rd = normalize(vec3(uv,-1));

    float y = M.xy == vec2(0) ? 0. : -(M.y/R.y * 1. - .5) * PI;
    mat2 rx = rot(.78), ry = rot(y+T*.0325);
    ro.yz *= rx;ro.xz *= ry;
    rd.yz *= rx;rd.xz *= ry;
    
    vec3 C = vec3(0);
    vec3  p = ro + rd;
    float atten = 1.,k = 1.,d = 0.;
    
    for(int i=0;i<148;i++)
    {
        vec2 ray = map(p);
        vec3 n=vec3(0);
        float m = ray.y;
        d = i<25? ray.x*.325:ray.x*.9;
        p += rd * d *k;

        if (d*d < 1e-7) {
            hitPoint = hit;
            sid = gid;

            C+=render(p,rd,ro,d,ray.y,n)*atten;
            if(m==1.||m==3.)break;

            p += rd*.01;
            k = sign(map(p).x);

            if(int(F.x)%2 != int(F.y)%2||m==5.) {
                atten *= m==5.?.75:.5;
                rd=reflect(-rd,n);
                p+=n*.02;
            }else{
                atten *= .85;
                rd=refract(rd,n,.9);
            }
           
        } 
        if(distance(p,rd)>55.) {break;}
    }
    C = mix( C, C*.5,clamp((uv.y+.1)*1.35,0.,1.));
    C = pow(C, vec3(.4545));
    fragColor = vec4(C,1.);
}
</script>
<div id="container" />