class Pen
  drawing: false
  color: '#000'
  strokeWidth: 2
  startX: null
  startY: null
  
  mousedown: =>
    console.log 'mousedown', @constructor.name
    @drawing = true

  mousemove: (evt) =>
    if @startX and @drawing is true
      console.log 'sup', @constructor.name
      @shape.graphics.beginStroke(@color)
        .setStrokeStyle(@strokeWidth, 'round')
        .moveTo(@startX, @startY)
        .lineTo(evt.stageX, evt.stageY)

      @app.stage.update()

    @startX = evt.stageX
    @startY = evt.stageY

  mouseup: =>
    console.log 'mouseup', @constructor.name
    @drawing = false
  
  constructor: (@app = {}) ->
    @events =
      mousemove: null
      mousedown: null
      mouseup: null
      
    @shape = new createjs.Shape()
    @app.stage.addChild @shape
    
  init: ->
    console.log "Activating #{@constructor.name}"
    @app.stage.mouseMoveOutside = true
    
    for stageEvent of @events
      console.log 'stageEvent', stageEvent
      @events[stageEvent] = @app.stage.on("stage#{stageEvent}", this[stageEvent], this)
    
    @app.stage.update()

  stop: ->
    console.log 'stop', @constructor.name
    for stageEvent, listener of @events
      console.log 'nuking', stageEvent
      @app.stage.off "stage#{stageEvent}", listener
      @events[stageEvent] = null
    
    @app.stage.update()

class Brush extends Pen
  strokeWidth: 10
  
class Eraser extends Pen
  strokeWidth: 10
  color: '#fff'

  
class Rectangle extends Pen

class App
  selected_tool: null

  constructor: (@stage) ->
    @tools =
        pen: new Pen(this)
        brush: new Brush(this)
        rect: new Rectangle(this)
        eraser: new Eraser(this)
        
    @activate 'pen'
    @stage.update()

    console.log 'app initialized'

  activate: (tool) ->
    @deactivate @selected_tool
    @selected_tool = tool
    @tools[tool].init()

  deactivate: (tool) ->
    @tools[tool]?.stop?()
    
  dump: =>
    console.log @stage.toDataURL()


toolbar = $ '#toolbar'
stage = new createjs.Stage 'appCanvas'
app = new App stage

toolbar.find('.tool').click (e) ->
  toolbar.find('.tool.selected').removeClass 'selected'
  $el = $(e.target).addClass 'selected'
  app.activate $el.data 'toolId'
  
toolbar.find('.debug').click app.dump